Come trovare il codice Product Key di Windows 10 utilizzando il prompt dei comandi

Da Silverio Galante

Se stai cercando il tuo codice Product Key in Windows 10, puoi trovarlo inserendo un comando rapido nel Prompt dei comandi. Ecco come, inoltre un piccolo trucco per trovare la chiave del prodotto utilizzando il registro di Windows.

Trova il tuo codice Product Key di Windows 10 usando il Prompt dei comandi

Per trovare il product key di Windows 10 utilizzando il Prompt dei comandi, devi aprire l’applicazione della riga di comando con privilegi di amministratore . Per fare ciò, digitare “cmd” nella barra di ricerca di Windows.

Il prompt dei comandi verrà visualizzato nei risultati della ricerca. Fare clic con il tasto destro del mouse e selezionare “Esegui come amministratore” dalla finestra visualizzata. Se richiesto, inserisci la password del tuo account di Windows.

Una volta aperto, copia e incolla il seguente comando e quindi premi il tasto Invio:

wmic path softwarelicensingservice get OA3xOriginalProductKey

Verrà quindi visualizzato il codice Product Key di 25 cifre.

Questo è tutto quello che c’è da fare. Probabilmente non è un codice che ricorderai molto facilmente. Se desideri un modo più rapido per accedere al tuo codice Product Key in futuro, puoi invece utilizzare il metodo del Registro di Windows.

Trova il tuo codice Product Key di Windows 10 utilizzando un metodo di registro di Windows

Il suggerimento di utilizzare il registro di Windows è stato inizialmente pubblicato da un utente (il cui account non è più attivo) nel forum di Microsoft .

Innanzitutto, apri Blocco note facendo clic con il pulsante destro del mouse in un punto qualsiasi del desktop, passando con il mouse su “Nuovo” e selezionando “Documento di testo” dal menu.

Copia e incolla questo codice nel Blocco note:

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Salvare dati su file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

Quindi, fai clic sul tab “File” e seleziona “Salva con nome”.

Puoi usare qualsiasi nome, ma deve essere un file .vbs. Puoi nominarlo come: productkey.vbs

Dopo aver inserito il nome del file, salva il file.

Ora puoi visualizzare il tuo codice Product Key di Windows 10 in qualsiasi momento aprendo il nuovo file.

potrebbe interessarti anche

7 Commenti

Leonardo Rossi Febbraio 11, 2021 - 10:10 pm

mi dà errore
riga 2
carattere1
radice non valida nella chiave di distema

Rispondi
Silverio Galante Febbraio 14, 2021 - 2:23 pm

Ciao Leonardo, ho aggiornato il codice, prova e fammi sapere.

Rispondi
Davide Febbraio 13, 2021 - 1:47 pm

ti prego rispondimi al più presto, ho fatto tutte le procedure, ho salvato i file eccetera , ho chiuso e aperto il file chiamato productkey.vbs con quella immagine di quella specie di pergamena pixellata verde acqua ma non mi apre nessun file con nessun codice, uscendo quel cerchio rosso con la x a sinistra e varie scritte ,come potrei risolvere dato che è già da 3 giorni che quel messaggio di scadenza mi perseguita? spero che mi risponderai al più presto,ciao.

Rispondi
Silverio Galante Febbraio 14, 2021 - 2:26 pm

Buongiorno Davide, se stai cercando un codice da inserire “nuovo” per verificare Windows questa non è la procedura adatta.
Questo file con questo codice legge il product key che hai installato attualmente. Utile nel caso di formattazioni dove si rende necessaria la reinstallazione di Windows.
Ciao.
P.S. Se invece cerchi il codice che hai attualmente in Windows ho aggiornato il codice dell’articolo.

Rispondi
Davide Maggio 18, 2021 - 10:29 am

ok grazie mille per la risposta

Rispondi
Salvatore Febbraio 27, 2021 - 10:00 pm

ho eseguito il tutto ma il risultato è:
BBBBB-BBBBB-BBBBB-BBBBB-BBBBB
COSA VUOL DIRE?
GRAZIE

Rispondi
Silverio Galante Febbraio 28, 2021 - 4:43 pm

Il problema sta nel fatto che hai un codice MAK (Multiple Activation Keys) o VLK (Volume License Keys).
Quando si utilizza la chiave per contratti multilicenza, la chiave del prodotto non viene memorizzata nel registro e temo che non sarà possibile trovarla a meno che non si acceda al Volume Licensing Service Center di Windows e si ottenga la chiave da lì.
Ciao.

Rispondi

Lascia un commento

17 + 19 =

Questo sito usa Akismet per ridurre lo spam. Scopri come i tuoi dati vengono elaborati.